אקסל: סיכום אוטומטי של נתונים לפי תנאי מגיליונות רבים באמצעות VBA

Option Explicit

Public Sub UpdateSummary()

    Dim ws As Worksheet, lastSummaryRow As Long, lastDataRow As Long
    Dim i As Long, personName As String, total As Double

    With ThisWorkbook.Worksheets("סיכום")

        lastSummaryRow = .Cells(.Rows.Count, "A").End(xlUp).Row

        For i = 2 To lastSummaryRow

            personName = Trim(.Cells(i, "A").Value)
            total = 0

            If personName <> "" Then

                For Each ws In ThisWorkbook.Worksheets

                    Select Case ws.Name

                        Case "גיליון ראשון", "גיליון אחרון", "סיכום"
                            'do nothing 

                        Case Else

                            lastDataRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row

                            If lastDataRow >= 2 Then
                                        total = total + Application.SumIf(   ws.Range("A2:A" & lastDataRow), personName,  ws.Range("H2:H" & lastDataRow))
                            End If

                    End Select

                Next ws

                .Cells(i, "B").Value = total

            Else
                .Cells(i, "B").ClearContents
            End If

        Next i

    End With

    MsgBox "הסיכום עודכן בהצלחה", vbInformation

End Sub